// Show the latitudes in green and the equator in magenta
// File by Michael Schmitt   (c) 1997-05-22
// m-schmitt@t-online.de   or   admin@esys.org

#version 3.0
#include "colors.inc"
#include "astro.inc"


global_settings { assumed_gamma 2.2 }

light_source { <5, 5,-20> color White }

camera {
   direction <0, 0, 4.5>
   location  <0, 0, -20>
   look_at   <0, 0, 0>
   right <1,0,0>         // x/y ratio
}

// Background

plane { z, 2000 pigment { color White } }

union {
   union {  // northern latitude
      intersection {  // angle plane
         plane { x,0 }
         cylinder  { <-0.001,0,0>,<0.001,0,0>, 1 }
         plane { -y,0 }
         plane { y,0 rotate x*-30 }
         pigment { color Blue filter 0.6 }
      }
      union {  // pointers
         object {   pointer                }
         object {   pointer   rotate x*-30 }
         pigment { color Blue }
      }
      rotate y*180
   }  // ends northern latitude
   union {  // southern latitude
      intersection {  // angle plane
         plane { x,0 }
         cylinder { <-0.001,0,0>,<0.001,0,0>, 1 }
         plane { y,0 }
         plane { -y,0 rotate x*15 }
         pigment { color Red filter 0.6 }
      } 
      union {  // pointers
         object {   pointer                }
         object {   pointer   rotate x*15  }
         pigment { color Red }
      }
      rotate y*-60
   }  // ends southern latitude
   sphere { <0.0, 0.0, 0.0>, 1
      pigment { color LightBlue filter 0.8 }
   }      
   object {   latitudes  }

   scale 2

   rotate <23,0,0>
   rotate <0,-60,0>

   finish {
      ambient 1
//      diffuse 0.2
      phong 1
   }
  
}