// Show the longitudes in yellow and the 0 meridian in red
// File by Michael Schmitt

#version 3.0
#include "colors.inc"
#include "astro.inc"


global_settings { assumed_gamma 2.2 }

light_source { <5, 5,-20> color White }

camera {
   direction <0, 0, 4.5>
   location  <0, 0, -20>
   look_at   <0, 0, 0>
   right <1,0,0>         // x/y ratio
}

// Background
plane { z, 2000 pigment { color White } }

union {
   union {  // eastern longitude
      intersection {  // angle plane
         plane { y,0 }
         cylinder  { <0,-0.001,0>,<0,0.001,0>, 1 }
         plane { x,0 }
         plane { -x,0 rotate y*-30 }
         pigment { color Red filter 0.6 }
      }
      union {  // pointers
         object {   pointer                }
         object {   pointer   rotate y*-28 }
         pigment { color Red }
      }
      rotate x*30
   }  // ends eastern longitude
   union {  // western longitude
      intersection {  // angle plane
         plane { y,0 }
         cylinder { <0,-0.001,0>,<0,0.001,0>, 1 }
         plane { -x,0 }
         plane { x,0 rotate y*15 }
         pigment { color Blue filter 0.6 }
      } 
      union {  // pointers
         object {   pointer                }
         object {   pointer   rotate y*15  }
         pigment { color Blue }
      }
      rotate x*-15
   }  // ends southern latitude
   sphere { <0.0, 0.0, 0.0>, 1
      pigment { color LightBlue filter 0.8 }
   }      
   object {   longitudes  }

   scale 2

   rotate <0,-128,0>
   rotate <23,0,0>
   rotate <0,-60,0>

   finish {
      ambient 1
//      diffuse 0.2
      phong 1
   }
  
}